phil ringnalda

A TrackBack at Sam Ruby’s that may or may not be spam, but sure looks like it to me, together with my increasingly crabby assessment of the results of TrackBack autodiscovery (I would hate it even if it didn’t have a bug that leads to multiple pinging, since “a TrackBack is a comment”, but not every link is a comment) made me think that it would be handy to have the “new TrackBack ping” notification email, usually a joyous thing, include a link to edit (and thus delete pings from) the entry or category that was pinged. Fortunately, it’s an easy hack, although the added bits are spread out a bit, so I’ll give you the whole “if we are sending email” bit to replace.

You’ll need to edit {your MT directory}/lib/MT/App/Trackback.pm, down around line 214 if you haven’t done any other hacking in it. New bits are highlighted, so you can see what mischief I’m getting up to:

MT 2.51 Version:

    if ($blog->email_new_pings) {
        require MT::Mail;
        my($author, $what, $editlink);
        my $path = MT::ConfigMgr->instance->CGIPath;
        $path .= '/' unless $path =~ m!/$!;
        if ($entry) {
            $author = $entry->author;
            $what = "entry " . $entry->id . " (" . $entry->title . ")";
            $editlink = $path . "mt.cgi?__mode=view&_type=entry&id=" .
             $entry->id . "&blog_id=" . $blog->id;
        } elsif ($cat) {
            require MT::Author;
            $author = MT::Author->load($cat->created_by);
            $what = "category " . $cat->id . " (" . $cat->label . ")";
            $editlink = $path . "mt.cgi?__mode=tb_cat_pings&blog_id=" .
             $blog->id . "&category_id=" . $cat->id;
        }
        if ($author && $author->email) {
            my %head = ( To => $author->email,
                         From => $author->email,
                         Subject =>
                             '[' . $blog->name . '] New TrackBack Ping to ' .
                             $what );
            MT::Mail->send(\%head, <<BODY);
A new TrackBack ping has been sent to your blog, on the
$what.

IP Address: @{[ $ping->ip ]}
URL: @{[ $ping->source_url ]}
Ping Title: @{[ $ping->title ]}
Weblog: @{[ $ping->blog_name ]}

Excerpt:
@{[ $ping->excerpt ]}

Edit at $editlink
BODY
        }
    }

MT 2.6 Version:

    if ($blog->email_new_pings) {
        require MT::Mail;
        my($author, $subj, $body, $editlink);
        my $path = MT::ConfigMgr->instance->CGIPath;
        $path .= '/' unless $path =~ m!/$!;
        if ($entry) {
            $author = $entry->author;
            $subj = $app->translate('New TrackBack Ping to Entry [_1] ([_2])',
                $entry->id, $entry->title);
            $editlink = $path . "mt.cgi?__mode=view&_type=entry&id=" .
             $entry->id . "&blog_id=" . $blog->id;
            $body = $app->translate('A new TrackBack ping has been sent to your weblog, on the entry [_1] ([_2])', $entry->id, $entry->title);
        } elsif ($cat) {
            require MT::Author;
            $author = MT::Author->load($cat->created_by);
            $subj = $app->translate('New TrackBack Ping to Category [_1] ([_2])',
                $cat->id, $cat->label);
            $editlink = $path . "mt.cgi?__mode=tb_cat_pings&blog_id=" .
             $blog->id . "&category_id=" . $cat->id;
            $body = $app->translate('A new TrackBack ping has been sent to your weblog, on the category [_1] ([_2])', $cat->id, $cat->label);
        }
        if ($author && $author->email) {
            my %head = ( To => $author->email,
                         From => $author->email,
                         Subject => '[' . $blog->name . '] ' . $subj );
            my $charset = $app->{cfg}->PublishCharset || 'iso-8859-1';
            $head{'Content-Type'} = qq(text/plain; charset="$charset");
            require Text::Wrap;
            $Text::Wrap::cols = 72;
            $body = Text::Wrap::wrap('', '', $body) . "\n\n" .
                 $app->translate('IP Address:') . ' ' . $ping->ip . "\n" .
                 $app->translate('URL:') . ' ' . $ping->source_url . "\n" .
                 $app->translate('Title:') . ' ' . $ping->title . "\n" .
                 $app->translate('Weblog:') . ' ' . $ping->blog_name . "\n\n" .
                 $app->translate('Excerpt:') . "\n" . $ping->excerpt . "\n\n" .
                 "Edit at " . $editlink;
                 
            MT::Mail->send(\%head, $body);
        }
    }

I wish I could say something like “Enjoy!”, but, at least it’s better than clicking your way through from the main menu when you need to use it.